OKWAVEのAI「あい」が美容・健康の悩みに最適な回答をご提案!
-PR-
解決
済み

Excelシートを固定長のテキストファイルに変換

  • 困ってます
  • 質問No.156680
  • 閲覧数851
  • ありがとう数5
  • 気になる数0
  • 回答数5
  • コメント数0

お礼率 69% (145/210)

エクセル2000で、シートをテキストファイル
(prnファイル)に落とすVBAを作っています。

現在、以下のようなコード(OK Webで教えていただいた
方法)で、スペース区切りでA5からC10までをテキスト
ファイルに落とす、というような方法を使っています。

ここから、A列は100バイト、B列は150バイト、
C列は50バイトというように列の長さを固定して
テキストファイルに落とすようにしたいのですが、
どのようにすればよろしいのでしょうか?


以下はプログラムで使っている変数名です。
・sMyFilenameは出力するファイル名
・lRowNumbは5行目から10行目までを指定。
・nColumNumbはA列からX列までを指定。


nFrn = FreeFile(0)
Open sMyFilename For Output As #nFrn 

For lRowNumb = 5 To 10
For nColumNumb = 1 To 3

sData = .Cells(lRowNumb, nColumNumb).Value

If nColumNumb < 3 Then
Print #nFrn, sData & " ";
Else
Print #nFrn, sData
End If

Next nColumNumb
Next lRowNumb

Close #nFrn
通報する
  • 回答数5
  • 気になる
    質問をブックマークします。
    マイページでまとめて確認できます。

質問者が選んだベストアンサー

  • 回答No.1
レベル12

ベストアンサー率 65% (276/422)

サンプルを作りました。

ファイル名などを固定にしていますが、そこら辺は読み替えてください。
それと毎回読んだデータをすぐに書きに行っていたので、一行ずつ書き込むように変更しています。
大きな違いはfixStrというオリジナル関数を追加しています。
この関数で、固定長の文字列として取得できます。

VBでは文字長に関係するときは
  StrConv("文字列", vbFromUnicode)
というのをよく使います。


Sub Main()
  Dim nFrn    As Long
  Dim lRowNumb  As Long
  Dim nColumNumb As Long
  Dim sData    As String
  
  Dim FixByte   As Variant '固定長バイト数をあらわす配列
  Dim strOutPut  As String  '出力する文字列
  Dim wkStr    As String  'ワークの文字列
  
  '各列のバイト数をセット(配列0の要素にダミーの値をセット)
  FixByte = Array(0, 100, 150, 50)

  nFrn = FreeFile(0)
  Open "c:\1.txt" For Output As #nFrn
  
    For lRowNumb = 5 To 10
      '出力文字の初期化
      strOutPut = ""
      For nColumNumb = 1 To 3
        'とりあえず書かれている内容を取得
        sData = Cells(lRowNumb, nColumNumb).Value
        
        '固定長のバイト数で調整を行う、ダミーの文字列として、" "スペースを使用
        wkStr = fixStr(sData, CLng(FixByte(nColumNumb)), " ")
        
        '文字列の連結を行う
        strOutPut = strOutPut & wkStr
      Next nColumNumb
      
      '文字列の出力
      Print #nFrn, strOutPut
    Next lRowNumb
  
  Close #nFrn
End Sub

'文字数をパラメータの文字列で調整して返す関数
'引数1.調整される文字列
'引数2.バイト長
'引数3.固定長の調整文字
Private Function fixStr(inStrings As String, inLength As Long, inDmyStr As String) As String
  Dim wkStr  As String  'ワークの文字列
 
  '引数の文字列に、引数の長さの分だけのv調整文字を追加して一時記憶
  wkStr = inStrings & String(inLength, inDmyStr)
 
  'FromUnicodeに変換
  wkStr = StrConv(wkStr, vbFromUnicode)
 
  '左からinLength分の文字を取得
  wkStr = LeftB(wkStr, inLength)
 
  'Unicodeに変換して返す
  fixStr = StrConv(wkStr, vbUnicode)
End Function
補足コメント
fuyu

お礼率 69% (145/210)

丁寧な回答ありがとうございます。

おかげさまで目的のプログラムは作れたのですが、
プログラムの一部で分からないことがあり、
できれば教えていただけないでしょうか?

・fixStrメソッドを呼び出した時のsDataがK
・CLng(FixByte(nColumNumb))が5
だった場合、

(1)'引数の文字列に、引数の長さの分だけの
調整文字を追加して一時記憶
  wkStr = inStrings & String(inLength,
inDmyStr)

でwkStrはKに5個のスペースがついた状態になるんだろう
というのは分かるのですが、(←間違っていたら教えて
ください)

次の
(2)FromUnicodeに変換 して
(3)inLength(5個)分の文字を取得
(4)Unicodeに変換
というのがよく分からず、実際にこのプログラムをコピー
して変数の動きを見てみたのですが、分かりません
でした。

(2)と(4)は何のためにやっていてどんな働きがあるので
しょうか?
投稿日時 - 2001-10-25 10:58:10
-PR-
-PR-

その他の回答 (全4件)

  • 回答No.2
レベル8

ベストアンサー率 33% (18/53)

ワウ もうサンプルがありましたか 私もサンプル作ってみました。 ちょっと列でのデータ長処理泥臭くやってみました。 #1の方が汎用的でスマートですね。 Sub test1() Dim sData As String Dim DLen As Long  '列でのデータ長さ Const sMyFilename As String = "C:\My Documents\OKW ...続きを読む
ワウ もうサンプルがありましたか
私もサンプル作ってみました。
ちょっと列でのデータ長処理泥臭くやってみました。
#1の方が汎用的でスマートですね。

Sub test1()
Dim sData As String
Dim DLen As Long  '列でのデータ長さ
Const sMyFilename As String = "C:\My Documents\OKWeb\test1.txt"

nFrn = FreeFile(0)
Open sMyFilename For Output As #nFrn


For lRowNumb = 5 To 10
  For nColumNumb = 1 To 3
   'とりあえずデータ取得
   sData = Cells(lRowNumb, nColumNumb).Value
   Select Case nColumNumb
     Case 1 '1列目
      DLen = 100 'byte
      sData = Left(sData, DLen)
      sData = sData & Space(DLen - Len(sData))
     Case 2  '2列目
      DLen = 150 'Byte
      sData = Left(sData, DLen)
      sData = sData & Space(DLen - Len(sData))
     Case 3 '3列目
      DLen = 50 'Byte
      sData = Left(sData, DLen)
      sData = sData & Space(DLen - Len(sData))
     Case Else
      MsgBox (" Error")
      Exit Sub
    End Select
    Print #nFrn, sData; '改行しない
   Next nColumNumb
    Print #nFrn, "" 'ここで改行
  Next lRowNumb

Close #nFrn
End Sub
お礼コメント
fuyu

お礼率 69% (145/210)

今回は半角文字のみだったので、SpaceとLenも使わせていただきました。回答ありがとうございました。非常に助かりました
投稿日時 - 2001-10-25 13:22:07


  • 回答No.3
レベル12

ベストアンサー率 65% (276/422)

urkさん(#2)への補足です。 >sData = Left(sData, DLen) >sData = sData & Space(DLen - Len(sData)) この部分はバイト数ではなく、文字数で行っています。 sDataに全角文字がないときはOKですが、もしあるのであればNGです。
urkさん(#2)への補足です。

>sData = Left(sData, DLen)
>sData = sData & Space(DLen - Len(sData))
この部分はバイト数ではなく、文字数で行っています。
sDataに全角文字がないときはOKですが、もしあるのであればNGです。
  • 回答No.4
レベル8

ベストアンサー率 33% (18/53)

そうですね。#2 は文字数なのでNGです。_(* *)_  wkStr = fixStr(sData, CLng(FixByte    (nColumNumb)), " ") でやらないといけません。
そうですね。#2 は文字数なのでNGです。_(* *)_
 wkStr = fixStr(sData, CLng(FixByte    (nColumNumb)), " ")
でやらないといけません。
  • 回答No.5
レベル12

ベストアンサー率 65% (276/422)

補足です。(StrConvについて) VBで文字列をそのままLen関数にかけると、文字数が返ってきます。LenBだと文字数の2倍の値が返ってきます。 一度 Dim wkByte() as Byte と宣言して wkByte = "あいbうcえお" '←半角と全角の混合 として、実行してみてください。 wkByteは1文字につき、配列2個を使用する変数に ...続きを読む
補足です。(StrConvについて)

VBで文字列をそのままLen関数にかけると、文字数が返ってきます。LenBだと文字数の2倍の値が返ってきます。

一度
Dim wkByte() as Byte
と宣言して
wkByte = "あいbうcえお" '←半角と全角の混合
として、実行してみてください。
wkByteは1文字につき、配列2個を使用する変数になっています。このときは0~13までの配列要素をもった配列になってると思います。
配列要素偶数番目には0以外の数字が入っているはずです。配列要素奇数番目には、0が入っていたり入っていなかったりすると思います。
それがポイントです。
奇数番目に0が入っているのは、その直前の配列要素の値で文字を表現していることになります。

その0の値を無視してカウントさせる処理をStrConvでやってると思っていただければ結構です。
お礼コメント
fuyu

お礼率 69% (145/210)

丁寧に教えていただいてありがとうございます。

まだ完全には理解できていませんが、少しイメージできました。

今回は非常に助かりました。ありがとうございました。
投稿日時 - 2001-10-25 13:14:59
このQ&Aのテーマ
このQ&Aで解決しましたか?
関連するQ&A
-PR-
-PR-
こんな書き方もあるよ!この情報は知ってる?あなたの知識を教えて!
このQ&Aにはまだコメントがありません。
あなたの思ったこと、知っていることをここにコメントしてみましょう。

その他の関連するQ&A、テーマをキーワードで探す

キーワードでQ&A、テーマを検索する
-PR-
-PR-
-PR-

特集


いま みんなが気になるQ&A

関連するQ&A

-PR-

ピックアップ

-PR-
ページ先頭へ