exeファイルのセキュリティ。

質問

社内用のメンテナンスプログラムを制作したのですが、同じプログラムで他社の製品にも使えてしまいます。たいした大きさではないので、フロッピーで十分なんですが社外に流失してしまうとこまってしまいます。
IPアドレスで確認すればいいのですが、登録していないようなものはどうしたらよいのでしょうか？
どなたか、教えていただけませんか？

回答No.4

TAGOSAKU7 · ベストアンサー

通信認証のサンプルを作成しました。
（正確に言うと、以前に作成したものがあって、それを抜粋しました）

プロジェクトは二つ必要で、サーバーとクライアントに分かれています。
それぞれにプロジェクトを作成して、EXEを作成してください。
基本はサーバーのEXEが立ち上がった状態で、クライアントのEXEを起動してください。
この書き込みの下の方に「共通の標準モジュール」を記してますが、[INIT_PORT][SERVER_NAME]の各定数があります。
こちらは環境に合わせて変更をしてください。
もし、一台のマシンで実験をするのであればSERVER_NAMEをご自分のマシン名に変更をしてください。

プログラムが正常に動くと、サーバー、クライントが交互に通信状況をメッセージボックスで知らせます。
これはあくまでサンプルなのでそのようにしてますが、サーバー側にはメッセージボックスの機能を使用しないでください。メッセージボックスが表示されている間は、他のユーザーとの通信ができなくなってしまいます。
（VBでそれを回避する方法があるのですが、動作が不安定になるために書きません）

このサンプルでは、互いに文字列を送信しています。
実践では、その文字列をパスワード認証に使用してはいかがでしょうか？

必要なもの

Project1.vbp(サーバー用)
フォーム
Winsock1(インデックスなし)
Winsock2(インデックスあり)

Project2.vbp(クライアント用)
フォーム
Winsock1(インデックスなし)

Winsockはメニューバーより
[プロジェクト]
[コンポーネント]
[Microsoft Winsock Control 6.0（かな？）]
を選択したらツールボックスにWinsockコントロールが現れます。
それをサーバー側に二つ、クライアント側に一つ、各フォームに貼り付けます。
サーバー側のWinsock2にはIndexプロパティに'０'ゼロをセットしてください。
その他のWinsockには値を入力しないでください。

あとは下のソースを貼り付けてください。
－－－－－サーバーのフォーム内のソース（ここから）－－－－－－－－－
Option Explicit

Private Sub Form_Load()
　　Me.Caption = "SERVER"

　　'ポートの初期化を行い、受信待ち状態にする
　　On Error GoTo PGMERR

　　With Me.Winsock1
　　　　.LocalPort = INIT_PORT
　　　　.Listen
　　End With

　　Exit Sub

PGMERR:
　　Call MsgBox("通信ポートに以上が見られました、終了いたします。", vbSystemModal, Me.Caption)
　　End
End Sub

'フォームが閉じる前に、Winsockを全て閉じる
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
　　Dim wkSock　As Winsock

　　With Me
　　　　.Winsock1.Close
　　　　For Each wkSock In .Winsock2
　　　　　　wkSock.Close
　　　　Next wkSock
　　End With
End Sub

'特定のクライアントのソケットを閉じたとき
Private Sub Winsock2_Close(Index As Integer)
　　With Me
　　　　.Winsock2(Index).Close
　　　　Unload .Winsock2(Index)
　　End With
End Sub

'メッセージデータの受信
Private Sub Winsock2_DataArrival(Index As Integer, ByVal bytesTotal As Long)
　　Dim strRecvData As String　　　 '送られてきたデータ
　　Dim lngRecvCnt　As Long　　　　 '送られてきたデータライン数
　　Dim valRecvAry　As Variant　　　'送られてきたデータをライン数のに分解し配列にして記憶

　　Dim wkVal　　　 As Variant　　　'受信したメッセージ１文を、IDとメッセージに分解して配列で記憶
　　Dim wkSType　　 As SOCKMSG_ID　 '分解した１文のID
　　Dim wkStr　　　 As String　　　 '分解した１文のメッセージ

　　Dim i　　　　　 As Long　　　　 'ループカウンタ

　　Dim wkMsg　　　 As String　　　 '送信するメッセージ

　　With Me

　　　　'メッセージを受け取る
　　　　.Winsock2(Index).GetData strRecvData

　　　　'受信メッセージを、メッセージ分の配列にする
　　　　valRecvAry = Split(strRecvData, vbCrLf)

　　　　'メッセージ数を取得
　　　　lngRecvCnt = UBound(valRecvAry)

　　　　'受信メッセージの分だけ、一文ずつ処理を行う
　　　　For i = 0 To lngRecvCnt - 1

　　　　　　'一文をIDとメッセージに分解
　　　　　　wkVal = Split(valRecvAry(i), vbNullChar)
　　　　　　wkSType = wkVal(0)
　　　　　　wkStr = wkVal(1)

　　　　　　Select Case wkSType
　　　　　　　　Case SOCKMSG_ID.ID1
　　　　　　　　　　wkMsg = "山川豊"
　　　　　　　　　　Call MsgBox("ID1で[" & wkStr & "]を受信しました" & vbNewLine & vbNewLine _
　　　　　　　　　　　　& "ID1で[" & wkMsg & "]を送信します", vbSystemModal, Me.Caption)
　　　　　　　　　　Call SendMsg(.Winsock2(Index), ID1, wkMsg)

　　　　　　　　Case SOCKMSG_ID.ID2
　　　　　　　　　　wkMsg = "起動してもいいよ"
　　　　　　　　　　Call MsgBox("ID2で[" & wkStr & "]を受信しました" & vbNewLine & vbNewLine _
　　　　　　　　　　　　& "ID2で[" & wkMsg & "]を送信します", vbSystemModal, Me.Caption)
　　　　　　　　　　Call SendMsg(.Winsock2(Index), ID2, wkMsg)

　　　　　　End Select
　　　　Next i
　　End With
PGMEND:
End Sub

'接続要求がきたら、新たなWinsockを用意する
Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
　　Dim lngNewIndex As Integer

　　lngNewIndex = 0
　　On Error Resume Next

　　With Me
　　　　'新たな受信装置を1つ追加する
　　　　Do
　　　　　　Err.Clear
　　　　　　lngNewIndex = lngNewIndex + 1
　　　　　　Load .Winsock2(lngNewIndex)
　　　　Loop Until Err.Number = 0&
　　　　On Error GoTo 0

　　　　.Winsock2(lngNewIndex).Accept requestID
　　End With
End Sub
－－－－－サーバーのフォーム内のソース（ここまで）－－－－－－－－－

－－－－－クライアントのフォーム内のソース（ここから）－－－－－－－
Option Explicit

'フォームロード時に接続を試みる
Private Sub Form_Load()
　　Me.Caption = "CLIANT"

　　With Me.Winsock1
　　　　.RemoteHost = SERVER_NAME
　　　　.RemotePort = INIT_PORT
　　　　.LocalPort = 0
　　　　.Connect
　　End With
End Sub

'サーバーが落ちた
Private Sub Winsock1_Close()
　　Call MsgBox("サーバーが落ちたー", vbSystemModal, Me.Caption)
　　Unload Me
End Sub

'サーバーと接続できた
Private Sub Winsock1_Connect()
　　Dim wkMsg　 As String

　　wkMsg = "岸部四郎"

　　Call MsgBox("接続できた" & vbNewLine & vbNewLine _
　　　　　　& "ID1で[" & wkMsg & "]を送信します", vbSystemModal, Me.Caption)
　　Call SendMsg(Me.Winsock1, ID1, wkMsg)
End Sub

'サーバーと接続できなかった
Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
　　Call MsgBox("接続できなかった", vbSystemModal, Me.Caption)
　　Unload Me
End Sub

'メッセージデータの受信
Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
　　Dim strRecvData As String　　　 '送られてきたデータ
　　Dim lngRecvCnt　As Long　　　　 '送られてきたデータライン数
　　Dim valRecvAry　As Variant　　　'送られてきたデータをライン数のに分解し配列にして記憶

　　Dim wkVal　　　 As Variant　　　'受信したメッセージ１文を、IDとメッセージに分解して配列で記憶
　　Dim wkSType　　 As SOCKMSG_ID　 '分解した１文のID
　　Dim wkStr　　　 As String　　　 '分解した１文のメッセージ

　　Dim i　　　　　 As Long　　　　 'ループカウンタ

　　Dim wkMsg　　　 As String　　　 '送信するメッセージ

　　With Me

　　　　'メッセージを受け取る
　　　　.Winsock1.GetData strRecvData

　　　　'受信メッセージを、メッセージ分の配列にする
　　　　valRecvAry = Split(strRecvData, vbCrLf)

　　　　'メッセージ数を取得
　　　　lngRecvCnt = UBound(valRecvAry)

　　　　'受信メッセージの分だけ、一文ずつ処理を行う
　　　　For i = 0 To lngRecvCnt - 1

　　　　　　'一文をIDとメッセージに分解
　　　　　　wkVal = Split(valRecvAry(i), vbNullChar)
　　　　　　wkSType = wkVal(0)
　　　　　　wkStr = wkVal(1)

　　　　　　Select Case wkSType
　　　　　　　　Case SOCKMSG_ID.ID1
　　　　　　　　　　wkMsg = "鳥羽一郎"
　　　　　　　　　　Call MsgBox("ID1で[" & wkStr & "]を受信しました" & vbNewLine & vbNewLine _
　　　　　　　　　　　　& "ID2で[" & wkMsg & "]を送信します", vbSystemModal, Me.Caption)
　　　　　　　　　　Call SendMsg(.Winsock1, ID2, wkMsg)

　　　　　　　　Case SOCKMSG_ID.ID2
　　　　　　　　　　Call MsgBox("ID2で[" & wkStr & "]を受信しました" & vbNewLine & vbNewLine _
　　　　　　　　　　　　& "通信を終了します", vbSystemModal, Me.Caption)

　　　　　　　　　　'''''ここに通信が正常にできたことを示すフラグを立てておく
　　　　　　　　　　Unload Me
　　　　　　End Select
　　　　Next i
　　End With
PGMEND:
End Sub
－－－－－クライアントのフォーム内のソース（ここまで）－－－－－－－

サーバー・クライアントのそれぞれに共通の標準モジュールとして、以下のソースを追加してください。
－－－－－共通の標準モジュール（ここから）－－－－－－－
Option Explicit

Public Enum SOCKMSG_ID
　　ID1 = 1
　　ID2 = 2
　　ID3 = 3
End Enum
Public Const INIT_PORT　As Long = 8000　'←このPORTは使用される確立が高いので、適当な値に変更したほうがいいかも？
Public Const SERVER_NAME As String = "PC_MACHINE_NAME"　'←サーバー用のEXEのをおくマシン名

Public Sub SendMsg(inSock As Winsock, inSendType As SOCKMSG_ID, inSendMsg As String)
　　Dim wkStr　 As String

　　With inSock
　　　　'通信が可能なときに通信する
　　　　If (.State = (sckConnected)) Then
　　　　　　'通信の書式は
　　　　　　'　1.通信を送るときのID（SOCKMSG_IDを自分で作成、オリジナルの番号を振る）
　　　　　　'　2.vbNullChar（IDとメッセージとの区切り文字）
　　　　　　'　3.メッセージ（任意の文字列）
　　　　　　'　4.vbCrLf（文末を示す）
　　　　　　wkStr = inSendType & vbNullChar & inSendMsg & vbCrLf

　　　　　　'メッセージを送る
　　　　　　.SendData wkStr
　　　　End If
　　End With
End Sub
－－－－－共通の標準モジュール（ここまで）－－－－－－－

お礼

そう簡単に作れるものではありませんよね。
本当にありがとうございます。
winsockは使ったことありますので、
サンプルから発展させられればと思います。
助かります。

回答No.3

TAGOSAKU7

サンプルを作ってみようと思うのですが・・・

機能１．ドメイン
「ドメイン」という意味はわかりますか？
まずこちらから「ネットワークにドメインサーバーがあるかないか」という質問をこしたいのですが、、、
会社にはサーバーがありますよね？
もし意味がわからなかったら、会社のサーバー管理者に
「うちのネットワークにはドメインサーバーがあるの？」と聴いてみてください。
ドメインサーバーがないのであれば、この方法は無理です。

機能２．通信
ファイルサーバーでも何でもいいので、一台のマシンが通信の受信待ち状態で待機するＥＸＥを起動する。
それで今回問題の社外に持ち出されたら困るＥＸＥを起動する。
このとき通信を行う。
通信ができないのであれば、ＥＸＥ終了

この二つの機能がメインです。
ですのでドメインを使用してるかどうかを教えてください。

ちなみに仕事の合間にサンプルを作成しておりますので（←いいのか？）、ちーと時間がかかると思います。

回答No.2

TAGOSAKU7

ykkw_2001さんのおっしゃる通り、環境次第でどうにでもなりそうですね。

ＩＰアドレスで確認しきれないということはＤＨＣＰを導入してるとか？
もしそれなら、ユーザー名が取れるし、ワークグループではなくドメインを使用したら、ネットワークに参加＝社内環境とできるのでは？
なので、ＥＸＥにドメイン固定のロジックを追加してしまえばよいと思います。

さらに認証パスワードを起動時に入力などなど。

サーバーにもうひとつのＥＸＥを用意して、そちらと通信が可能なときのみＥＸＥが起動可能という方法もあります。

お礼

ありがとうございます。
勉強不足で、”ＥＸＥにドメイン固定のロジックを追加してしまえばよいと”
理解できません。
具体例を挙げていただければ幸いです。

回答No.1

ykkw_2001

利用環境次第でどうにでもなりそうですけど・・・

たとえば、ＩＰで確認はダメなように書かれていますが、イントラネットの特定アドレスのマシンで認証するとか。
社内専用アプリケーションの存在をレジストリで確認してから、動作させるとか。

ＩＤ＋パスワードに時間を絡めて、１回だけ実行できるようにするとか。

はずしてたらゴメンです。

お礼

どうもありがとうございました。
説明不足ですみません。
>社内専用アプリケーションの存在をレジストリで確認してから・・・
ん～。むずかしいですね。
アプリで社内専用がわかればいいんですけど・・。
パスワードは平気で渡す輩がいて・・。