EXCELの罫線について

質問

表を作成し、外枠を太線に、内側の横罫線を細線にしています。
複数ページにまたがった時に、最終ページ以外は最終行が細線になります。
行数が変わっても、最終行を太線にする方法があったら教えて下さい。

回答No.1

nishi6

回答がありませんね。Excelの印刷機能だけではしかたないでしょうね。
それでは回答にならないと思い、参考に下記のマクロを書いてみました。
印刷範囲を設定して、ツール→マクロ→マクロでLineChangeを実行すれば各頁を太枠で囲んだ印刷になると思います。今は印刷プレビューにしてあります。PrintPreviewをPrintOutにすれば印刷します。(Excel2000です)

やってることは単純で、
　(1)外枠の太線の種類を調べる(どのサイズか不明のため)
　(2)改頁位置を調べる(最終行が空白でない場合のために画面を動かしています)
　(3)各改頁位置の１行前の下線を調べた太線にする
　(4)印刷プレビュー
　(5)変更した太線を元の細線に戻す
です。印刷前後に処理時間を要します。(印刷枚数によりますが)
ちょっと長くなりました。ご参考に。

ツール→マクロ→Visual Basic Editor でVBE画面に移り、挿入→標準モジュール で標準モジュールを挿入し、そこに貼り付けます。
'(Public prtRg ～ End Sub の範囲をコピーして貼り付けます)

Public prtRg As Range '印刷範囲
Public colNum As Integer '印刷範囲列数
Public endRowNum As Long '印刷範囲の最終行
Public LineWeight As Long '太線の種類
Public cl As Integer '列カウンタ

Public Sub LineChange()
　　On Error GoTo ErrorHandler '印刷範囲を設定していない場合

　　Set prtRg = Range("Print_Area") '印刷範囲の列数、最終行を求める
　　　　colNum = prtRg.Columns.Count: endRowNum = prtRg.Rows.Count
　　　　prtRg.Cells(endRowNum, 1).Select '印刷範囲の最終行に移動

　　'太線の種類を調べる
　　Dim rg As Range 'セル
　　For Each rg In prtRg
　　　　If rg.Borders(xlEdgeLeft).LineStyle <> xlNone Then
　　　　　　LineWeight = rg.Borders(xlEdgeLeft).Weight '太線の種類
　　　　　　Exit For
　　　　End If
　　Next

　　'Application.ScreenUpdating = False '画面更新を止める
　　LineChange_Sub xlThin, LineWeight '頁の最後の線を太くする
　　ActiveSheet.PrintPreview '今はプレビュー。PrintOutで印刷
　　LineChange_Sub LineWeight, xlThin '頁の最後の線を細くする
　　'Application.ScreenUpdating = True '画面更新

　　Exit Sub
ErrorHandler:
　　If Err = 1004 Then MsgBox "印刷範囲を設定して実行して下さい"
End Sub

'頁の最後の線の太さを変える
Public Sub LineChange_Sub(srcWeight, chgWeight)
　　Dim cot As Integer '改行カウンタ
　　Dim hPB As Integer '改行位置
　　Dim pageEnd As Range '頁の最後の行

　　hPB = ActiveSheet.HPageBreaks.Count
　　For cot = 1 To hPB
　　　　Set pageEnd = ActiveSheet.HPageBreaks(cot).Location.Offset(-1, 0)
　　　　For cl = 1 To colNum
　　　　　　'頁の最後
　　　　　　With pageEnd.Offset(0, cl - 1).Borders(xlEdgeBottom)
　　　　　　　　If .LineStyle <> xlNone Then
　　　　　　　　　　If .Weight = srcWeight Then '線の太さを変える
　　　　　　　　　　　　.Weight = chgWeight
　　　　　　　　　　End If
　　　　　　　　End If
　　　　　　End With
　　　　Next
　　Next
End Sub